0.96 Inch Beyaz Oled Lcd Modül

0.96 Inch Beyaz Oled Lcd Modül

128x64 Pixel IIC I2C Seri 0.96” Ekran Gösterge SSD1306 3.3V 5V Matrix Display

Adafruit SSD1306 kütüphanesi ile çalıştırabilirsiniz. Stoktaki ürünleri I2C adresleri değişebiliyor. Bazı model ürünlerde I2C adresini doğru tanımlamanız gerekmektedir.

     0.96" Oled lcd küçük projeleriniz için çok uygun ekran çözümüdür. 128x64 yüksek çözünülürlükte ve yüksek parlaklıktadır. Yazı ve resim olarak görsel çıktılar gerektiren uygulamalar için idealdir.  Siyah taban üzerine beyaz renktedir. I2C haberleşme portu üzerinden kullanılır. İnce ve küçük yapısı ile devrelerde az yer kaplar.  Geniş sıcaklık aralığında çalışabilir. Düşük güç harcamasına sahiptir.

     SSD1306 sürücü entegresi lcd içinde gömülü olarak bulunmaktadır. DC 3.3V / 5V besleme ile çalışabilir. Arduino ve pek çok microkontrolör ile kolayca kullanılır.
  

Özellikler:

• 0.96 inch oled lcd
• 4 Pin erkek header bağlantı soketi
• Haberleşme: IIC
• Ekran rengi: Beyaz
• Çalışma voltajı:  DC 3V / 5V
• Sürücü entegre: SSD1306 ( Lcd içerisinde gömülü )
• Çözünülürlük: 128 x 64 pixel
• Düşük güç harcaması: Tam ekran 0.08W
• Yüksek parlaklık kontrast
• Açı: 160 dereceden düşük
• Arduino, 8051 serisi mcu, MSP430, STM32 ve benzeri entegreler ile kullanılabilir.
• Çalışma sıcaklığı:   -30C  /  70C
• Aktif ekran alanı:  21.74mm x 11.2mm
• Boyutlar:: 27mm x  27mm
• Ağırlık: 5gr

Pin açıklaması:

• GND: Toprak
• VCC: Besleme
• SCL: I2C Saat
• SDA: I2C Data

Paket içeriği:

• 1 Adet   0.96 Inch Beyaz Oled Lcd Modül

I2C adresi parti parti değişebilir. Yapayzeka uygulamalarından destek alarak farklı örnekler deneyebilirsiniz. Dalgalı bir çizimgeliyorsa ekrana ürünün çalıştığını ama I2C adresinde sorun olduğunu gösterebilir.

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH  128
#define SCREEN_HEIGHT 64
#define OLED_RESET    -1

Adafruit_SSD1306 display(
  SCREEN_WIDTH,
  SCREEN_HEIGHT,
  &Wire,
  OLED_RESET
);

uint8_t oledAddress = 0;
uint8_t testPage = 0;
unsigned long lastChange = 0;

bool i2cDeviceExists(uint8_t address) {
  Wire.beginTransmission(address);
  return Wire.endTransmission() == 0;
}

void showTest(uint8_t page) {
  display.clearDisplay();
  display.setTextColor(SSD1306_WHITE);

  if (page == 0) {
    display.drawRect(0, 0, 128, 64, SSD1306_WHITE);

    display.setTextSize(2);
    display.setCursor(18, 10);
    display.print("ROBIZ");

    display.setTextSize(1);
    display.setCursor(25, 35);
    display.print("SSD1306 TEST");

    display.setCursor(30, 49);
    display.print("Adres: 0x");
    display.print(oledAddress, HEX);
  }

  else if (page == 1) {
    // Bütün pikselleri yak
    display.fillScreen(SSD1306_WHITE);
  }

  else {
    // Dama deseni
    for (int y = 0; y < SCREEN_HEIGHT; y += 8) {
      for (int x = 0; x < SCREEN_WIDTH; x += 8) {
        if (((x / 8) + (y / 8)) % 2 == 0) {
          display.fillRect(x, y, 8, 8, SSD1306_WHITE);
        }
      }
    }
  }

  display.display();
}

void setup() {
  Serial.begin(115200);

  Wire.begin();
  Wire.setClock(100000);
  delay(200);

  // Beklenen iki adresi otomatik bul
  if (i2cDeviceExists(0x3C)) {
    oledAddress = 0x3C;
  }
  else if (i2cDeviceExists(0x3D)) {
    oledAddress = 0x3D;
  }
  else {
    Serial.println("OLED bulunamadi!");
    Serial.println("GND, VCC, SCL ve SDA baglantilarini kontrol edin.");

    while (true) {
      delay(1000);
    }
  }

  Serial.print("OLED bulundu. I2C adresi: 0x");
  Serial.println(oledAddress, HEX);

  if (!display.begin(SSD1306_SWITCHCAPVCC, oledAddress)) {
    Serial.println("SSD1306 baslatilamadi!");

    while (true) {
      delay(1000);
    }
  }

  showTest(0);  // İlk görüntüyü hemen göster
  lastChange = millis();
}

void loop() {
  if (millis() - lastChange >= 2000) {
    lastChange = millis();

    testPage = (testPage + 1) % 3;
    showTest(testPage);
  }
}